Weight and Fractional Counts Options

 

The WT option lets you apply non-integer (fractional) weighting to procedures. It is used when the sample differs from known population parameters. To apply case weighting, you must first create a variable that contains a weight.

The following example computes weights for each of three groups and saves the weight for subsequent analyses. The CaseWeight variable will become the last variable in the study.

 

STUDY SEGMENT

NEW (N7) "CaseWeight"

IF GROUP = 1 THEN COMPUTE CaseWeight = 0.4172

IF GROUP = 2 THEN COMPUTE CaseWeight  = 0.8735

IF GROUP = 3 THEN COMPUTE CaseWeight = 1.0963

SAVE

..

Subsequent procedures could then apply weights to the analyses using the WT option. Parentheses are required around the variable name. Since an exclamation point is used as a suffix, weighting will become the default for all subsequent analyses. In this example, both the frequencies and descriptive statistics procedures would weight the data. If the exclamation point had been excluded, weighting would only be used in the frequencies procedure.

 

STUDY SEGMENT

FREQ V1-V10

OPTIONS WT=(CaseWeight)!

..

DESC V11

..

Unlike other options, the WT option (with a ! suffix) only applies to the current StatPac session. If you quit StatPac and restart it, the WT option will be set to N (None). This is done to prevent a potentially serious mistake. For example, suppose you run a procedure file with weighting and then end StatPac. The next day you run StatPac and begin processing a different procedure file. If the WT option was persistent, weighting might inadvertently be applied to the new procedure file when you didn't intend it to be… and worse, you might not realize it.

You can turn weighting on and off by using WT=(VariableName) and WT=N. In the following example, weighting is applied to the first, second procedures, but not the third and fourth procedures.

 

STUDY MYRESEARCH

TITLE Weighted Frequencies for: (#)

FREQ V1

OPTIONS WT=(WeightVariable)!

..

TITLE Weighted Descriptive Statistics for: (#)

DESC V2

..

TITLE Unweighted Frequencies for: (#)

FREQ V1

OPTIONS WT=N!

..

TITLE Unweighted Descriptive Statistics for: (#)

DESC V2

..

The FC (fractional counts) option my be set to Y or N. It sets whether the N's (counts) in the reports will be shown as integers or decimal values. The FC option only applies when weighting is used. In unweighted data, the counts will always be integer values (whole numbers).

Weights are easily calculated as the desired percentage divided by the observed percentage (or the desired count divided by the observed count). For example, suppose you know that the population has 50% males and 50% females. This is called a known population parameter. Your survey sample, however, has 40% males and 60% females. If the responses to other variables were different for males and females, your reports might present a distorted estimate of the population. Weighting would be used to eliminate the gender sampling error. The weight for males would be 50/40 and the weight for females would be 50/60. In the following example, the first procedure calculates a GENDERWEIGHT variable and saves it. The second procedure uses the WT option to weight the data based on the GENDERWEIGHT variable.

 

NEW (N5) "GENDERWEIGHT"

IF SEX="M" THEN COMPUTE GENDERWEIGHT = 50/40

IF SEX="F" THEN COMPUTE GENDERWEIGHT = 50/60

SAVE

..

FREQ SOMEVARIABLE

OPTIONS WT=(GENDERWEIGHT)

..

 

Copyright © 2017 StatPac Inc., All Rights Reserved